#!/bin/csh
#######################################################################################################################################
# #
# D E T O U R A G E E N N O I R D ' U N E I M A G E E N V R A I E S C O U L E U R S : #
# #
# #
# Utilisation : #
# #
# $xci/detourage.23$Z <imageA> <imageR> [<Sgradient> [<Sfiltre> [<et_logique> [<Filtrer> [<Conv> [<FConv>]]]]]] #
# . #
# /|\ #
# | #
# ------------ "3" parce que travaille sur les trois composantes (ROUGE, VERTE et BLEUE) #
# #
# #
# Author of '$xci/detourage.23$Z' : #
# #
# Jean-Francois Colonna (LACTAMME, 20060606135602). #
# #
#######################################################################################################################################
set nomA=$1
set nomR=$2
set Sgradient=$3
set Sfiltre=$4
set EtLogique=$5
set Filtrer=$6
# Parametre introduit le 20050920185006... #
set Convoluer=$7
set FConvol=$8
# Parametres introduits le 20091202095402... #
setArgum Sgradient 28
setArgum Sfiltre 80
setArgum EtLogique $EXIST
# Permet de choisir entre '$xci/and$X' ('$EXIST') et '$xci/multi_02.01$X' ('$NEXIST'), #
# l'avantage de '$xci/and$X' etant de conserver les couleurs de l'image Argument... #
# Ce choix a ete introduit le 19970725175500, sachant que dans les versions anterieures #
# il faut considerer qu'il etait a l'etat '$NEXIST' puisque seul '$xci/multi_02.01$X' etait #
# utilise... #
setArgum Filtrer $NEXIST
setArgum Convoluer $NEXIST
setArgum FConvol `GetParam $xci/convol.02$X facteur_points`
FileTmpB nomT
# Generation d'un nom temporaire... #
execRVB $xci/gradient.01$X A=$nomA%s R=$nomT%s $formatI
# Calcul du gradient pour chacune des trois composantes de l'image vraies couleurs Argument. #
if ($Filtrer == $EXIST) then
FileTmpB nomT1
FileTmpB nomT2
# Generation de noms temporaires... #
$xci/gauss$X R=$nomT$W $formatI
# Generation systematique d'un champ gaussien du type 'v $xiio/GAUSS.8110' ; en effet, on ne #
# peut utiliser cette derniere image que si on est en mode 'Suq', 'Sud', 'Std' ou 'Sdu' #
# (c'est-a-dire en format "carre" de dimension lineaire egale a une puissance de 2). #
$xci/maximum$X A1=$nomT$ROUGE A2=$nomT$VERTE $formatI | \
$xci/maximum$X A2=$nomT$BLEUE $formatI | \
$xci/seuil$X seuil=$Sgradient $formatI | \
$xci/complement$X R=$nomT1 $formatI
$xci/filtre.01$X A=$nomT1 N=$nomT$W seuil=$Sfiltre avertir_non_implicite=FAUX R=$nomT2 $formatI
$xci/acces$X A=$nomT2 R=$nomT $formatI
# Calcul du maximum des trois gradients que l'on seuille, puis que l'on complemente, puis #
# qu'enfin on filtre... #
FileTmpE nomT1
FileTmpE nomT2
# Puis destruction des images de manoeuvre... #
else
$xci/maximum$X A1=$nomT$ROUGE A2=$nomT$VERTE $formatI | \
$xci/maximum$X A2=$nomT$BLEUE $formatI | \
$xci/seuil$X seuil=$Sgradient $formatI | \
$xci/complement$X $formatI | \
$xci/acces$X R=$nomT $formatI
# Calcul du maximum des trois gradients que l'on seuille, puis que l'on complemente. #
endif
if ($EtLogique == $EXIST) then
execRVB $xci/and$X A1=$nomA%s A2=$nomT R=$nomR%s $formatI
else
execRVB $xci/multi_02.01$X A1=$nomA%s A2=$nomT R=$nomR%s $formatI
endif
# Et enfin detourage la ou le gradient est fort... #
if ($Convoluer == $EXIST) then
$xci/complement$X A=$nomT R=$nomT $formatI
execRVB $xci/convol.02$X A=$nomR%s N=$nomT V=$BLANC F=$BLANC R=$nomR%s fp=$FConvol mncv=FAUX $formatI
# Et enfin convolution fonction du gradient inverse (introduit le 20091202095402)... #
else
endif
FileTmpE nomT
# Puis destruction des images de manoeuvre... #